Développement de jeux avec Vala et SDL

Le premier fichier que nous allons éditer se nomme : configure.ac. Le code suivant montre le fichier, une fois modifié pour les besoins de notre projet.

AC_INIT([brickval], [0.1.0], [me@lesharris.com], [brickval])
AC_CONFIG_SRCDIR([src/Makefile.am])
AC_CONFIG_HEADER(config.h)
AM_INIT_AUTOMAKE([dist-bzip2])
AM_MAINTAINER_MODE

AC_PROG_CC
AM_PROG_CC_C_O
AC_DISABLE_STATIC
AC_PROG_LIBTOOL

AC_PATH_PROG(VALAC, valac, valac)
AC_SUBST(VALAC)

AH_TEMPLATE([GETTEXT_PACKAGE], [Package name for gettext])
GETTEXT_PACKAGE=brickval
AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, "$GETTEXT_PACKAGE")
AC_SUBST(GETTEXT_PACKAGE)
AM_GLIB_GNU_GETTEXT
IT_PROG_INTLTOOL([0.35.0])

AC_SUBST(CFLAGS)
AC_SUBST(CPPFLAGS)
AC_SUBST(LDFLAGS)

GLIB_REQUIRED=2.12.0
SDL_REQUIRED=1.2.0
GEE_REQUIRED=0.1.3

PKG_CHECK_MODULES(BRICKVAL, glib-2.0 >= $GLIB_REQUIRED gobject-2.0 >= $GLIB_REQUIRED gee-1.0 > $GEE_REQUIRED)
AC_SUBST(BRICKVAL_CFLAGS)
AC_SUBST(BRICKVAL_LIBS)

VALA_PACKAGES="--pkg gee-1.0 "
SDL_AUX_LIBS=""

PKG_CHECK_MODULES(SDL, sdl >= $SDL_REQUIRED)
AC_SUBST(SDL_CFLAGS)
AC_SUBST(SDL_LIBS)
VALA_PACKAGES="$VALA_PACKAGES--pkg sdl "

AC_CHECK_HEADERS(SDL/SDL_gfxPrimitives.h,
        SDL_AUX_LIBS="$SDL_AUX_LIBS-lSDL_gfx ",
        AC_MSG_ERROR([SDL_gfx required but not found.])
        )
VALA_PACKAGES="$VALA_PACKAGES--pkg sdl-gfx "

AC_CHECK_HEADERS(SDL/SDL_image.h,
        SDL_AUX_LIBS="$SDL_AUX_LIBS-lSDL_image ",
        AC_MSG_ERROR([SDL_image required but not found.])
        )
VALA_PACKAGES="$VALA_PACKAGES--pkg sdl-image "

AC_CHECK_HEADERS(SDL/SDL_mixer.h,
        SDL_AUX_LIBS="$SDL_AUX_LIBS-lSDL_mixer ",
        AC_MSG_ERROR([SDL_mixer required but not found.])
        )
VALA_PACKAGES="$VALA_PACKAGES--pkg sdl-mixer "

AC_CHECK_HEADERS(SDL/SDL_ttf.h,
        SDL_AUX_LIBS="$SDL_AUX_LIBS-lSDL_ttf ",
        AC_MSG_ERROR([SDL_ttf required but not found.])
        )
VALA_PACKAGES="$VALA_PACKAGES--pkg sdl-ttf "

AC_SUBST(SDL_AUX_LIBS)
AC_SUBST(VALA_PACKAGES)

AC_CONFIG_FILES([Makefile
        data/Makefile
        data/backgrounds/Makefile
        data/sprites/Makefile
        src/Makefile
        po/Makefile.in])

AC_OUTPUT

Ouvrez le fichier original configure.ac généré par vala-gen-project et comparez les deux. Le principal apport est l'ajout de modules qui sont vérifiés dans PKG_CHECK_MODULES, quelques nouveaux Makefile dans AC_CONFIG_FILES, deux nouvelles variables dans VALA_PACKAGES et SDL_AUX_LIBS ainsi qu'un tas de choses au milieu de AC_CHECK_HEADER. Si cela vous paraît alarmant, ne paniquez pas !
Souvenez-vous que vous n'avez à faire ceci que cette fois seulement, et donc, cela n'est pas aussi compliqué que cela en a l'air.

Si vous comprenez tout ce qui est expliqué ici, sentez vous libre d'allez à la partie suivante.

Pour ceux qui sont toujours là, voici ce qui se passe dans le fichier configure.ac. La plupart des distributions Linux modernes jouent avec un utilitaire nommé pkg-config qui fournit un moyen facile de rechercher les options du compilateur que requiert une bibliothèque pour être compilée. PKG_CHECK_MODULES dans votre ficher configure.ac vérifie simplement l'existence de ces bibliothèques et s'assure que vous avez les bonnes versions de ces dernières d'installées.
Il stocke ensuite les options de compilations dans BRICKVAL_CFLAGS et BRICKVAL_LIBS.

Brickval dépend aussi de bibliothèques SDL auxiliaires que la commande pkg-config ne peut vérifier, donc nous contrôlons leur existence via AC_CHECK_HEADERS. Nous faisons l'hypothèse un peu naïve que si les fichiers d'entête existent, alors la bonne version de la bibliothèque est installée. Cela est la plupart du temps le cas, mais cela peu poser un problème potentiel. Si le fichier d'entête est là, il rajoute les options de compilation pour cette bibliothèque dans SDL_AUX_LIBS, autrement, il imprime une erreur et stoppe la configuration du projet.

À ce stade, vous devriez noter que la variable VALA_PACKAGES est en réalité superflue pour ce programme puisque toutes les bibliothèques sont nécessaires et non plus facultatives. Ceci démontre un moyen de générer dynamiquement la liste des paquets requis pas valac à partir du fichier de configuration lui-même.
Si la bibliothèque est installée, alors c'est le paquet vala qui s'ajoute à la variable VALA_PACKAGES qui sera utilisée plus tard dans notre Makefile afin passer ces derniers au compilateur.

Finalement, nous avons ajouté quelques Makefile supplémentaires dans AC_CONFIG_FILES que Brickval devra utiliser. Ces ajouts concernent principalement la manière dont nous installer nos graphiques de données.
L'ajout de src/Makefile sera expliqué dans la partie suivante.

La manière dont vala-gen-projet créé le fichier Makefile.am construit le projet d'une telle façon que l'exécutable généré est créé à la racine du répertoire du projet.
Pour Brickval, nous voulons suivre une approche plus traditionnelle et créer l'exécutable dans le sous-répertoire src.
Grâce à cela, le fichier Makefile.am peut se simplifier de la manière suivante :

SUBDIRS = src po data

EXTRA_DIST = \
        intltool-extract.in \
        intltool-update.in \
        intltool-merge.in

DISTCLEANFILES = \
        intltool-extract \
        intltool-update \
        intltool-merge \
        po/.intltool-merge-cache

Ceci indique aux autotools qu'il y a des Makefile supplémentaires dans les sous-répertoires src, po, et data dont ils auront besoin d'exécuter afin de pouvoir compiler le projet. Il rajoute également quelques fichiers supplémentaires qui seront distribués avec le paquet final.

Le dossier pour ce fichier Makefile.am n'existe pas encore, nous allons donc le créer ainsi que les sous-répertoires dont nous aurons besoin pour lui plus tard :

mkdir -p data/sprites
mkdir data/backgrounds
cd data

Maintenant, créons le fichier Makefile.am avec votre éditeur de texte préféré et placez ce qui suit dedans :

SUBDIRS = sprites backgrounds

Bien, puisque nous avons créé les sous-répertoires, mettons-y quelques images :

wget http://www.lesharris.com/valagamedev/gfx.tar.gz

Ces graphiques sont du thème Deadfish pour LBreakout2 et ont été créés par Johannes Kroll (j-kroll (at) gmx (point) de). Décompressez le fichier où vous voulez et déplacez le fichier bg.png dans le sous-répertoire background et le reste dans le sous-répertoire sprites.

Même si les données sont encore là, nous devons indiquer aux autotools que ces données doivent être installées quelque-part. Nous allons faire ça maintenant.

II-B-3-a. data/backgrounds/Makefile.am▲

Backgroundsdir = $(datadir)/brickval/backgrounds

Backgrounds_DATA = \
        bg.png

EXTRA_DIST = \
        $(Backgrounds_DATA)

II-B-3-b. data/sprites/Makefile.am▲

Spritesdir = $(datadir)/brickval/sprites

Sprites_DATA = \
        bricks.png \
        extras.png \
        life.png \
        paddle.png

EXTRA_DIST = \
        $(Sprites_DATA)

Ouf, nous avons presque fini de créer tous les Makefile.am !
Il en reste juste un et c'est le plus complexe puisque c'est celui qui compile le code vala.
Il doit contenir ce qui suit :

VALA_CFLAGS = \
        --vapidir ../vapi \
        --pkg config \
        $(VALA_PACKAGES)

AM_CPPFLAGS = \
        -DDATADIR=\"$(datadir)\" \
        -DPACKAGE_DATADIR=\""$(datadir)/brickval"\" \
        -DSPRITE_DIR=\""$(datadir)/brickval/sprites"\" \
        -DBACKGROUND_DIR=\""$(datadir)/brickval/backgrounds"\" \
        -DPACKAGE_LOCALEDIR=\""$(datadir)/locale"\" \
        $(BRICKVAL_CFLAGS) \
        $(SDL_CFLAGS) \
        -include $(CONFIG_HEADER)

BUILT_SOURCES = brickval.vala.stamp

bin_PROGRAMS = brickval

brickval_VALASOURCES = \
        brickval.vala

brickval_SOURCES = \
        $(brickval_VALASOURCES:.vala=.c) \
        $(brickval_VALASOURCES:.vala=.h)

brickval.vala.stamp: $(brickval_VALASOURCES)
        $(VALAC) -C $(VALA_CFLAGS) $^
        touch $@

brickval_LDADD = \
        $(BRICKVAL_LIBS) \
        $(SDL_LIBS)     \
        $(SDL_AUX_LIBS)

La première partie de ce fichier définit les options de compilation qui seront passées au compilateur Vala, valac. Nous passerons vapidir et le paquet config dans la partie qui va suivre, mais vous noterez que c'est l'endroit où nous mettons notre variable VALA_PACKAGES que nous avons créé dans le fichier configure.ac à utiliser.
La seconde partie définie plusieurs constantes qui seront définies au moment de la compilation pour notre projet. Celles-ci, aussi, sont étroitement rattachées au mystérieux paquet config dont nous discuterons plus tard.
C'est également l'endroit où sont placés les options pour le compilateur gcc.

La majeur partie du reste de ce fichier correspond au modèle et est généré pour vous grâce à vala-gen-project (je l'ai simplement déplacé dans ce Makefile.am). Cependant, deux parties en particulier sont intéressantes pour vous. La première est brickval_VALASOURCES. C'est l'endroit où vous spécifiez tous les fichiers source qui seront utilisés pour créer l'application. Dans l'immédiat, nous n'avon que brickval.vala ici. Puisque brickval.vala n'existe pas encore, renommons le fichier main.vala en brickval.vala :

mv main.vala brickval.vala

C'est dorénavant bien mieux.
La dernière partie dont vous devriez être conscients est la partie brickval_LDADD. C'est l'endroit où nous plaçons les variables qui contiennent les options de compilation des bibliothèques, dans notre cas, les bibliothèques pour Brickval lui-même et SDL.

Félicitations, l'environnement de configuration est prêt !
Toutefois, nous n'avons pas encore tout à fait fini.
Il reste le mystérieux paquet vapidir ainsi que celui de configuration à traiter.